@echo off
setlocal
echo.
echo All files (swhx.exe, oed.exe, ResHacker.exe) must exist in this current directory.
if exist swhx.exe goto :a
echo Extract swhx.exe from swhx-1,2,0.zip with a command like
echo   unzip -j "swhx-1,2,0.zip" swhx/tools/swhx.exe
echo -- note that the quotation marks are required under Windows because of the
echo [illegal] commas in the ZIPfile name.
goto :eof
:a
for /F %%A in ("swhx.exe") do if %%~zA==147456 goto :b
echo swhx.exe is the wrong filesize! Should be 147456 bytes. Aborting...
goto :eof
:b
if exist oed.exe goto :c
echo Download OED_update_4-0-3.exe from
echo  ftp://oeduser:oup123@fds.oup.com/OED_update_4-0-3.exe
echo and install it first! Copy oed.exe to this directory, if necessary.
goto :eof
:c
for /F %%A in ("oed.exe") do if %%~zA==6897664 goto :d
echo oed.exe is the wrong filesize! Should be 6897664 bytes. Aborting...
goto :eof
:d
if exist ResHacker.exe goto :e
echo Download reshack.zip from
echo  http://www.angusj.com/resourcehacker/reshack.zip
echo and extract ResHacker.exe from it (and copy to this directory, if necessary).
goto :eof
:e
if exist oedNEW.rc del oedNEW.rc
if exist Icon_1.ico del Icon_1.ico
if exist oedNEW.exe del oedNEW.exe
if exist swhxNEW.exe del swhxNEW.exe
ResHacker.exe -extract oed.exe,oedNEW.rc,icongroup,,
ResHacker.exe -delete swhx.exe,swhxNEW.exe,icongroup,,
ResHacker.exe -addoverwrite swhxNEW.exe,oedNEW.exe,Icon_1.ico,icongroup,1,0
if exist oedNEW.exe goto :x
echo Error: "oedNEW.exe" not found! Aborting...
goto :eof
:x
del oedNEW.rc
del swhxNEW.exe
del ResHacker.ini
del ResHacker.log
move /Y oedNEW.exe oed.exe >NUL
move /Y Icon_1.ico oed.ico >NUL
echo A new "oed.exe" created in this directory
echo  (with the older date of swhx.exe, which is correct).
echo Done
goto :eof